10000 REM take "direct sun" observation on uvb port ** gi routine 160196 **
10001 REM IBM
10002 REM 130296 changed to show correct filter in datafile.
10003 REM Made by Lars Opedal at the University of Oslo,Renewed by AD and FT
10005 DATA gi
10010 IF Q8%=0 THEN RETURN:REM if no uvb port
10020 IF DN%<>8 THEN RETURN:REM if no disk recording
12000 UC%=0:ZL%=0:WL$="1":WU$="6":CX$="50":REM -14499 take direct sun obs on uvb port
12010 FLT$="0":TR$="s"+"a":REM azimuth tracking only
12015 GOSUB 2450:REM take brewer temp
12020 OPEN DD$+"dum.dta" FOR OUTPUT AS 8
12030 PRINT#8, DA$+" "+MO$+" "+YE$;:REM print data header date+dt+cy+temp
12040 PRINT#8, " dt "+str$(T1)+" cy "+CX$+" te "+TE$;
14010 GOSUB 6610:GOSUB 6635:M1$=STR$(ER%*3/4):GOSUB 9870:REM prism to uvb
14020 M5$="0":GOSUB 6650:REM filter #2
14040 TD=1500:GOSUB 7000:GOSUB 7800:GOSUB 6700:REM open iris
14050 LOCATE ,SP:PRINT "4 - Brewer azimuth to sun
14055 LOCATE ,SP:PRINT "5 - Director prism to uvb sensor"
14060 GOSUB 9650:REM wait till ready
14065 PRINT#4,"Taking GI measurements"
14070 GOSUB 7800:O1$="":GOSUB 9450:GOSUB 7500:REM test intensity
14080 FLT$=STR$(INT(VAL(M5$)/64+.5))
14090 CZ$=CX$:GOSUB 9710:GOSUB 8000:MS(0)=11:REM start obs and zero sums
14299 :
14300 REM get gi data
14310 GOSUB 9670
14320 MT$="":GOSUB 9900:REM wait till finished and get data
14330 IF HF%=1 THEN 14570:REM home flag terminates gi reading
14340 IF XN=1 THEN 14080:REM restart obs
14345 GOSUB 8600
14350 PRINT#8, " flt "+FLT$+" "+H$;
14360 GOSUB 7810:PRINT#8,USING " ###.## ##.###";ZA;M2:REM zenith angle & mu
14370 FOR IM=WL TO WU
14380 IF IM<2 THEN PRINT#8,USING " ####";F(IM);:GOTO 14400
14390 PRINT#8,USING " ##########";F(IM);
14400 NEXT
14410 PRINT#8,
14450 CLOSE 8
14460 B$= JD$+YF$+"."+NO$
14470 SHELL "COPY "+DD$+"GI"+B$+"+"+DD$+"dum.dta "+DD$+"GI"+B$
14500 RETURN
14570 PRINT CL$:LOCATE ,SP:PRINT "GI measurement terminated":CLOSE 8:RETURN
65529 REM *** dummy line ***